# file: $ISIP_BASE/app/communicator/kb/Grammar/query_distance.gra
# version: $Id: query_distance.gra 9945 2005-02-11 20:22:11Z elliott $

############### Query Direction Rules #################
[query_distance]
	([Query_Distance] [depart_arrive])
	([Query_Distance] [arriveloc])
	([Query_Distance] [departloc])
	([Query_Distance] *[what_distance])
;

[Query_Distance]
	([_query_distance])
;

[_query_distance]
#A- SAMPLE UTTERANCES COVERED BY THE FOLLOWING GRAMMAR
#1- is walmart close to kroger near hwy 12
	(CAN FAR *be *located VICINITY NEAR)
	(CAN FAR *be *located VICINITY)

#B- SAMPLE UTTERANCES COVERED BY THE FOLLOWING GRAMMAR
#1- how many miles is it to the hampton inn
#2- how far from walmart to kroger
#3- should i walk or drive to wendy's
#4- how long will it take to the courthouse grill
#4- how long should i walk to msu
#5- once you turn onto university drive from barr avenue, how far down university drive is the hunter henry center
	(*AN_ITEM HOW_FAR *CAN *[that] *take)
	(*AN_ITEM HOW_FAR *CAN [i] [go])
	(*AN_ITEM HOW_FAR *[the] NEAR CAN *[the] FAR)
	(*AN_ITEM CAN [i] [go] *or [go])
	(*[whats] *[the] distance BETWEEN)

#C- SAMPLE UTTERANCES COVERED BY THE FOLLOWING GRAMMAR
#1- am i closer to bell building supply or east mississippi lumber
	(*[is] *[i] VICINITY FAR1 *or *FAR2 *or *FAR3)

#D- SAMPLE UTTERANCES COVERED BY THE FOLLOWING GRAMMAR
#1- to drive from msu campus to walmart is it faster to take highway 12 or highway 82
#2- is hwy 12 or hwy 82 faster to go from msu campus to walmart
#3- which one is faster, hwy 12 or hwy 82 to get walmart from msu campus
	(*to *GET_GO [depart_arrive] IS_IT FAR1 or FAR2 *or *FAR3)
	(*[is] FAR1 or FAR2 *or *FAR3 *VICINITY *to *GET_GO)

#E- SAMPLE UTTERANCES COVERED BY THE FOLLOWING GRAMMAR
#1- starting from walmart, i will go to kroger and then to wendy's, can you estimate the distance for that route
	(*[some_place] [departloc] I CAN GET_GO *to FAR1 *and *THEN [arriveloc])

BETWEEN
	(between NEAR and FAR)
	([depart_arrive])
THEN
	(then)
	(next)
	(following [the])
IS_IT
	([is] [that] VICINITY to GET)
	([whats] [direction] [is] VICINITY)
GET
	(use)
	(take)
	([get])
	(go on)
GET_GO
	([get] *back)
	([go] *back)
	(make *it *back)
	(arrive)
VICINITY	
	(nearby)
	(around *here)
	(within walking distance *of)
	(in the neighborhood *of)
	(faster)
	(shorter)
	(closer *to)
	(close *to)
	(close *from)
	(near *to)
	(adjacent *to)
	(adjacency *of)
	(in *[the] vicinity *of)
	(outside)
AN_ITEM
	(*[once] *[i] *MOVE *[on] [some_place] [on] [some_place])
MOVE
	(move)
	(turn)
	(take)
	([go])
	([get])
I
	([i])
	([i_m])
CAN
	([is])
	([can])
HOW_FAR
	([how] [far] *down)
	([how] many miles)
FAR
	([Arrive_Loc] *[Arrive_Near])
FAR1
	([Arrive_First])
FAR2
	([Arrive_Second])
FAR3
	([Arrive_Third])
NEAR
	([Depart_Loc] *[Depart_Near])
;

#F- SOME AUXILIARY UTTERANCES THAT MAY FOLLOW REAL UTTERANCES
#1- can you estimate the distance for that route
[what_distance]
	(CAN I GIVE *[the] distance [of] [the] [direction] *[of] *[me])
	([whats] *[the] distance)
	(HOW_FAR [is] [the])

HOW_FAR
	([how] [far] *down)
	([how] many miles)
GIVE
	([estimate])
	([estimates])
	([tell])
	([show])
	([get])
I
	([i])
	([i_m])
CAN
	([is])
	([can])
;
