# file: $ISIP_BASE/app/communicator/kb/Grammar/query_list.gra
# version: $Id: query_list.gra 9945 2005-02-11 20:22:11Z elliott $

###### Drive Domain Specific Rules #############
[query_list]
	([Query_List] FAR *or *FAR *[what_way])
	([Query_List] *[of] [Arrive_Loc] *[vicinity])
	([Query_List] *[on] *[City_Name] [Arrive_Loc])
	([Query_List] *[what_way])
	([whats] [Arrive_Loc] [can] [vicinity] [Depart_Loc])
FAR
	([Arrive_Loc] *[Arrive_Near])
;

[Query_List]
	([_query_list])
;

[_query_list]
#A - SAMPLE UTTERANCES COVERED BY THE FOLLOWING GRAMMAR
#1- what restaurant is close to the court house
#2- which walmart is close to kroger
	([whats] [Arrive_Loc] [is] [Arrive_Near])
	(what [is] *[the] *[spec_way] [Arrive_Loc])

#B - SAMPLE UTTERANCES COVERED BY THE FOLLOWING GRAMMAR
#1- where can i buy some souvenirs in starkville
#2- i want to find some place where i buy some fruit
#3- where can i go to get some footwear
	(WHERE_HOW *[i] *CAN *[i] *[go] *to BUY *[the])

#C - SAMPLE UTTERANCES COVERED BY THE FOLLOWING GRAMMAR
#1- list all chinese restaurants in starkville
#2- can you list me all graduate students in butler
	(*CAN *[i] LIST *[me] *ALL FAR *[on] *FAR1 *[on] *[City_Name]) 
	(I_WANT FAR *or *[the] *[some_place] *[vicinity] *[on] *[City_Name])

#D - SAMPLE UTTERANCES COVERED BY THE FOLLOWING GRAMMAR
#1- how many pizza hut's are there in starkville
#1- which pizza hut's can you show me in starkville
#3- what pizza hut's are really available in starkville
#4- what academic units can i find in simrall building
#5- what are the academic units in simrall building in msu campus
#6- how many faculties or schools are in msu campus
#7- what shuttle bus routes stop at the coliseum
#8- what shuttle bus route will take me to the coliseum
#9- does shuttle bus maroon route stop at allen hall
	(HOW_MANY FAR THERE *[on] *FAR1 *[on] *[City_Name])
	(WHAT FAR *CAN *[i] SHOW *[me] *[on] *FAR1 *[on] *[City_Name])
	(CAN FAR SHOW *[on] *FAR1 *[on] *[City_Name])

#E - SAMPLE UTTERANCES COVERED BY THE FOLLOWING GRAMMAR
#1- i can use some suggestion for a nice restaurant around here
#2- how about a nice restaurant around here
#3- i am interested in finding a place to eat, for example pizza hut
	(*IAM *CAN WANT *THE RECOMMEND FOR)
	(*IAM *CAN LIKE *[the] [some_place] PREFER FAR)
	([how] about)

#F - SAMPLE UTTERANCES COVERED BY THE FOLLOWING GRAMMAR
#1- i need gas tell me the nearest shell station and how far
	(*[i] *[want] *[some_place] SHOW *[me] *to FAR *and HOW_FAR)

LIKE
	(interested in [doing_things])
	([want])
	([get])
PREFER
	([i] [want])
	(for example)
	(for instance)
	([how] about)
THERE
	([can] [i] *[really] [get] *[of] *[me])
	([is] *[really] located)
	([is] *[really] [available])
	([is] *there)
HOW_FAR
	([how] [far] *down)
	([how] many miles)
FOR
	(to [get] *[the])
	([of] *[the])
I_WANT
	(*[i] [want] *to *[get])
	(IAM *[is] looking for)	
IAM
	([i])
	([i_m])
WHERE_HOW
	(HOW)
	([i] [want] *to *[get] *[the] [an_address] WHATS)
WHATS
	([on] [which])
	([whats])
WHAT
	(who [is])
	([whats])
	(HOW_MANY)
HOW
	([how])
	([whats])
BUY
	([buy])
	([get])
CAN
	([can])
	([is])
ALL
	([of])	
	([the])
	(all *[the])
	(*[the] [suggestion] [of])
	(*[the] [an_address] [of])
SHOW
	([get])
	([show])
	([tell])
	([suggest])
	(direct)
	(take)
	(lead)
	(stop)
	(pass by)
LIST
	(show *[me] *[the] *list *[of])
	(list)
	(tell)
	([suggest])
	(have *[the] [suggestion] [of])
	(get *[the] [suggestion] [of])
	(get *[me] *[the] list [of])
	(give *[me] *[the] list [of])
HOW_MANY
	([whats])
	([how] many)
FAR
	([Arrive_Loc] *[Arrive_Near])
FAR1
	([Arrive_First])
FAR2
	([Arrive_Second])
NEAR
	([Depart_Loc] *[Depart_Near])
THE
	([the])
	([its])
WANT
	([want])
	(use)
	(entertain)
RECOMMEND
	([suggestion])
	([suggest])
;

